17 8月 15 SAS绘图即学即用系列连载4.1-线图

by sxlion

SAS绘图即学即用系列连载4.1 –曲线图：以下代码可以拷贝到SAS编辑器中，直接使用；稍作更改便可得到自己满意的图形。以下来自一本关于SAS绘图的书稿（未出版草稿），均为本人原创。完整代码详见SAS资源资讯列表 www.saslist.net

4.1 线图

4.11 曲线图

1
2
3
4
5
6
7
8
9

FILENAME file "d:\SAS_charts\sample411.png";
goptions reset=all device=png gsfname=file/*设置图片格式和存放点*/
hsize=8cm vsize=6cm ; /* 设置绘图区域大小 */
symbol value=none interpol=j CI=orange width=3; /* 设置线点属性 */
proc gplot data=sashelp.stocks;
plot high*date;
where stock="IBM" and ('01feb90'd <= date <= '01feb91'd);
run;
quit;

4.12 分组曲线图

1
2
3
4
5
6
7
8
9
10
11

FILENAME file "d:\SAS_charts\sample413.png";
goptions reset=all device=png gsfname=file/*设置图片格式和存放点*/
hsize=8cm vsize=6cm ; /* 设置绘图区域大小 */
symbol1 value=none interpol=join CI=red width=2;
symbol2 value=none interpol=join CI=blue width=2;
symbol3 value=none interpol=join CI=orange width=2;
proc gplot data=sashelp.stocks;
plot high*date=stock;
where ('01feb90'd < date < '01feb91'd);
run;
quit;

4.13 双/多曲线图

1
2
3
4
5
6
7
8
9
10
11

FILENAME file "d:\SAS_charts\sample414.png";
goptions reset=all device=png gsfname=file/*设置图片格式和存放点*/
hsize=10cm vsize=8cm ; /* 设置绘图区域大小 */
symbol1 value=none interpol=join CI=red L=2 width=1; /*L:设置线型 */
symbol2 value=none interpol=join CI=orange L=1 width=2;
symbol3 value=none interpol=join CI=green L=3 width=1;
proc gplot data=sashelp.stocks;
plot high*date close *date low*date /overlay ;
where stock="IBM" and ('01feb90'd < date < '01feb91'd);
run;
quit;

4.14 双坐标曲线图

1
2
3
4
5
6
7
8
9
10
11

FILENAME file "d:\SAS_charts\sample415.png";
goptions reset=all device=png gsfname=file/*设置图片格式和存放点*/
hsize=10cm vsize=8cm ; /* 设置绘图区域大小 */
symbol value=none interpol=j CI=red width=1; /* 设置线属性 */
symbol2 value=none interpol=j CI=black width=1; /* 设置点属性 */
proc gplot data=sashelp.stocks;
plot high*date/vzero;
plot2 volume*date;
where stock="IBM" and ('01feb90'd <= date <= '01feb91'd);
run;
quit;

4.15 其他修饰：

参考线、图例、坐标轴、标题、脚注

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

FILENAME file "d:\SAS_charts\sample416.png";
goptions reset=all device=png gsfname=file/*设置图片格式和存放点*/
hsize=12cm vsize=8cm ; /* 设置绘图区域大小 */
symbol1 value=none interpol=join CI=red width=2;/* 设置点属性 */
symbol2 value=none interpol=join CI=orange width=2;
symbol3 value=none interpol=join CI=green width=2;
axis1 order= ('01jan86'd to '01jan06'd by 1461) LABEL=( "Period") minor=none offset=(0.2 cm); /*调整坐标轴的显示、改变轴标签内容*/
axis2 order= (0 to 250 by 50) LABEL=(angle=90 "") major=none minor=none; /*调整坐标轴的显示、改变轴标签内容和位置*/
legend1 label=none
position=(top right inside)
mode=share;
Title H=0.4cm "Three company's stock from '01JAN86' to '01JAN06' ";
Footnote justify=left "Data resource: sashelp.stocks" ;
proc gplot data=sashelp.stocks;
plot close*date=stock /
haxis=axis1 vaxis=axis2
vref=50 to 200 by 50 lvref=1 CVREF=black WVREF=1
legend=legend1 ;
run;
quit;

原创文章: ”SAS绘图即学即用系列连载4.1-线图“，转载请注明：转自SAS资源资讯列表

本文链接地址: http://saslist.net/archives/409

Tags: proc gplot, SAS, 曲线图, 画图
Filed in 精选代码 with 0 Comments

05 8月 15 SAS绘图即学即用系列连载4.0-点图

by sxlion

SAS绘图即学即用系列连载4.0–点图：以下代码可以拷贝到SAS编辑器中，直接使用；稍作更改便可得到自己满意的图形。以下来自一本关于SAS绘图的书稿（未出版草稿），均为本人原创。完整代码详见SAS资源资讯列表 www.saslist.net

4.0 点图

4.01 散点图

也可使用SYMBOL全局选项来改变点的属性。

1
2
3
4
5
6
7
8

FILENAME file "d:\SAS_charts\sample401.png";
goptions reset=all device=png gsfname=file/*设置图片格式和存放点*/
hsize=10cm vsize=8cm ; /* 设置绘图区域大小 */
symbol color=black value=dot ; /* 设置点属性 */
proc gplot data=sashelp.class;
plot weight*height/ vzero;
run;
quit;

4.02 分组散点图

1
2
3
4
5
6
7
8
9

FILENAME file "d:\SAS_charts\sample402.png";
goptions reset=all device=png gsfname=file
hsize=8cm vsize=8cm ; /* 设置绘图区域大小   */
symbol1 color=blue value=square ;    /* 设置各分组数据散点的属性 */
symbol2 color=red value=squarefilled   ;
proc gplot data=sashelp.class;
plot weight*height=sex/vzero; /* 使用绘图程序必须语句和选项*/
run;
quit;

4.03 双坐标轴散点图

1
2
3
4
5
6
7
8
9
10

FILENAME file "d:\SAS_charts\sample403.png";
goptions reset=all device=png gsfname=file
hsize=12cm vsize=8cm ; /* 设置绘图区域大小 */
symbol1 color=blue value=squarefilled ; /* 设置各分组数据散点的属性 */
symbol2 color=black value=dot ;
proc gplot data=sashelp.class;
plot weight*age /vzero; /* 使用绘图程序必须语句和选项*/
plot2 height*age /vzero; /* 使用绘图程序必须语句和选项*/
run;
quit;

4.04 象限图其他调整和修饰：点标记、参考线、修饰坐标轴、标题脚注

标记数据点和参考线

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17

FILENAME file "d:\SAS_charts\sample404.png";
goptions reset=all device=png gsfname=file
hsize=10cm vsize=10cm ; /* 设置绘图区域大小 */
symbol1 color=orange value=dot H=2 POINTLABEL=("#name" JUSTIFY=center) ; /* 设置数据点的属性 */
axis1 order= (50 to 74 by 12) LABEL=( "身高/英寸") major=none minor=none; /*调整坐标轴的显示、改变轴标签内容*/
axis2 order= (40 to 140 by 50) LABEL=(angle=90 "体重/磅") major=none minor=none; /*调整坐标轴的显示、改变轴标签内容和位置*/
Title H=0.5cm font="MingLiU" "班级男生身高分布图" ;
Footnote justify=left "Data resource: sashelp.class" ;
proc gplot data=sashelp.class;
plot weight*height /
haxis = axis1 /*指定横坐标设置为前面全局设置坐标axis1*/
vaxis =axis2 /*指定纵坐标设置为前面全局设置坐标axis2*/
href = 62 chref=black /* 增加参考线*/
vref = 90 cvref=black;
where sex="男" ;
run;
quit;

原创文章: ”SAS绘图即学即用系列连载4.0-点图“，转载请注明：转自SAS资源资讯列表

本文链接地址: http://saslist.net/archives/403

Tags: gplot, sas绘图, sxlion, 散点图
Filed in 精选代码 with 0 Comments

17 8月 15 SAS绘图即学即用系列连载4.1-线图